***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Oct 31, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt BZT52-C3V3 A K 
.param
+vc0 = 1.346e-10	vc1 = 5.216e-9		vc2 = 1.300		vc3 = 2.006e-7		vc4 = 8.455
+tc1 = 1.281e-2		tc2 = 1.721e-2		tc3 = 5.301e-3		tc4 = 2.021e-3
.func irpwr(v) {(vc0+vc1*v^vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*v^vc4)*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irpwr(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1 
***** dc model parameter *****
+ is = 2.042e-14	   n = 1.145		  rs = 4.499e-1
+ibv = 1e-3		 nbv = 3.0		  bv = 3.3
+ikf = 2.148e-1
***** capacitance parameter *****
+cjo = 1.811e-10	   m = 3.008e-1		  vj = 5.961e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.123		 xti = 3
+trs1 = 9.735e-4	trs2 = 6.385e-6		tikf = 8e-3
+tbv1 = -5.608e-4	tbv2 = 7.722e-7	
.ends BZT52-C3V3
*$
